Page 1 of 2 12 LastLast
Results 1 to 20 of 26

Thread: Looking for a Garrison Script template

  1. #1

    Default Looking for a Garrison Script template

    these are the general requirements, i dont demand that all are met ofc, i am willing to compromise if necesary

    need a garrison script that

    1. Works in AI vs AI situations, to make factions die less

    2. Is advanced in terms of efficiency and doesnt slow the game too much like many old scripts

    3. Only gets triggered every 6 turns

    4. If possible, units are created the moment the settlement is under siege (this is to avoid siege with catapuls/trebuchets and insta attack before the garrison is recruited)

    5. Units are disbanded after siege ends

    6. Doesnt work for player (when player controlled settlement gets sieged no units will be recruited)

    7. Works in hotseat mode, i play my single player campaigns in hotseat mode cause i like to change factions every now and then

    8. Simple to use template (or as simple as possible), preferably one where all i have to do is change counter/settlement/unit names
    You know you've played too much Stainless Steel when in every other mod you play you think cavalry is too weak.

  2. #2
    Gigantus's Avatar The trouble with having an open mind, of course, is that people will insist on coming along and trying to put things in it
    Patrician Moderator Emeritus Administrator Emeritus Modding Emeritus

    Join Date
    Aug 2006
    Location
    Goa - India
    Posts
    46,607
    Blog Entries
    24

    Default Re: Looking for a Garrison Script template

    There is no simple template in view of the conditions that need to be met.

    Hot seat compatibility - no problem, really
    disbanding - requires dedicated units with custom ability entry, restricts number of settlements that can be monitored as ALL garrison units of a faction will be disbanded
    No player - use 'local_faction condition, which covers any hotseat player
    Instant creation - see example
    Cool down - not advisable as it will lead to exploits, intentional or not

    Script from 1648, the script will terminate after 100 turns based on the thought 'if a faction still needs that help after 100 turns then it has no right to exist'. The units used are copies of existing units that were given a G suffix and the custom attribute garnison (German for garrison). Units get created at the start of the attack (not the siege), preventing zero turn siege exploits.

    Code:
        ;=== Garrison Script ===
        
        declare_counter Bremen_siege
        declare_counter Stade_siege
        declare_counter Nordenham_siege
        declare_counter Stuttgart_siege
        declare_counter Moempelgard_siege
        declare_counter Aschaffenburg_siege
        declare_counter Mainz_siege
        declare_counter Erfurt_siege
        declare_counter Heiligenstadt_siege
        declare_counter Muenchen_siege
        declare_counter Freising_siege
        
        ;--- mustering garison ---
        monitor_event GeneralAssaultsResidence TargetFactionType hungary
            and IsTargetRegionOneOf Reichsstadt_Bremen
            and I_SettlementUnderSiege Bremen
            if I_TurnNumber < 100
                create_unit Bremen, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Bremen, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Bremen, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Bremen, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Bremen_siege 1
            end_if
            if I_TurnNumber > 99
                terminate_monitor
            end_if
        end_monitor
        
        monitor_event GeneralAssaultsResidence TargetFactionType hungary
            and IsTargetRegionOneOf Erzbistum_Bremen
            and I_SettlementUnderSiege Stade
            if I_TurnNumber < 50
                create_unit Stade, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Stade, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Stade, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Stade, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Stade_siege 1
            end_if
            if I_TurnNumber > 49
                terminate_monitor
            end_if
        end_monitor
        
        monitor_event GeneralAssaultsResidence TargetFactionType hungary
            and IsTargetRegionOneOf Butjadingen
            and I_SettlementUnderSiege Nordenham
            if I_TurnNumber < 50
                create_unit Nordenham, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Nordenham, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Nordenham, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Nordenham, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Nordenham_siege 1
            end_if
            if I_TurnNumber > 49
                terminate_monitor
            end_if
        end_monitor
        
        monitor_event GeneralAssaultsResidence TargetFactionType turks
            and IsTargetRegionOneOf Herzogtum_Wuerttemberg
            and I_SettlementUnderSiege Stuttgart
            if I_TurnNumber < 100
                create_unit Stuttgart, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Stuttgart, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Stuttgart, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Stuttgart, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Stuttgart_siege 1
            end_if
            if I_TurnNumber > 99
                terminate_monitor
            end_if
        end_monitor
        
        monitor_event GeneralAssaultsResidence TargetFactionType turks
            and IsTargetRegionOneOf Grafschaft_Moempelgard
            and I_SettlementUnderSiege Moempelgard
            if I_TurnNumber < 50
                create_unit Moempelgard, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Moempelgard, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Moempelgard, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Moempelgard, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Moempelgard_siege 1
            end_if
            if I_TurnNumber > 49
                terminate_monitor
            end_if
        end_monitor
        
        monitor_event GeneralAssaultsResidence TargetFactionType egypt
            and IsTargetRegionOneOf Erzbistum_Mainz
            and I_SettlementUnderSiege Aschaffenburg
            if I_TurnNumber < 100
                create_unit Aschaffenburg, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Aschaffenburg, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Aschaffenburg, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Aschaffenburg, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Aschaffenburg_siege 1
            end_if
            if I_TurnNumber > 99
                terminate_monitor
            end_if
        end_monitor
        
        monitor_event GeneralAssaultsResidence TargetFactionType egypt
            and IsTargetRegionOneOf Stadt_Mainz
            and I_SettlementUnderSiege Mainz
            if I_TurnNumber < 50
                create_unit Mainz, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Mainz, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Mainz, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Mainz, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Mainz_siege 1
            end_if
            if I_TurnNumber > 49
                terminate_monitor
            end_if
        end_monitor
        
        monitor_event GeneralAssaultsResidence TargetFactionType egypt
            and IsTargetRegionOneOf Stadt_Erfurt
            and I_SettlementUnderSiege Erfurt
            if I_TurnNumber < 50
                create_unit Erfurt, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Erfurt, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Erfurt, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Erfurt, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Erfurt_siege 1
            end_if
            if I_TurnNumber > 49
                terminate_monitor
            end_if
        end_monitor
        
        monitor_event GeneralAssaultsResidence TargetFactionType egypt
            and IsTargetRegionOneOf Eichsfeld
            and I_SettlementUnderSiege Heiligenstadt
            if I_TurnNumber < 50
                create_unit Heiligenstadt, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Heiligenstadt, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Heiligenstadt, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Heiligenstadt, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Heiligenstadt_siege 1
            end_if
            if I_TurnNumber > 49
                terminate_monitor
            end_if
        end_monitor
        
        monitor_event GeneralAssaultsResidence TargetFactionType portugal
            and IsTargetRegionOneOf Herzogtum_Bayern
            and I_SettlementUnderSiege Muenchen
            if I_TurnNumber < 100
                create_unit Muenchen, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Muenchen, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Muenchen, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Muenchen, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Muenchen_siege 1
            end_if
            if I_TurnNumber > 99
                terminate_monitor
            end_if
        end_monitor
        
        monitor_event GeneralAssaultsResidence TargetFactionType portugal
            and IsTargetRegionOneOf Bistum_Freising
            and I_SettlementUnderSiege Freising
            if I_TurnNumber < 50
                create_unit Freising, BuergerwehrG, num 4, exp 0, arm 0, wep 0
                create_unit Freising, GrenadiereG, num 1, exp 0, arm 0, wep 0
                create_unit Freising, MusketiereG, num 2, exp 0, arm 0, wep 0
                create_unit Freising, PikeniereG, num 3, exp 0, arm 0, wep 0
                set_counter Freising_siege 1
            end_if
            if I_TurnNumber > 49
                terminate_monitor
            end_if
            
        end_monitor
        
        ;--- siege is over ---
        monitor_event FactionTurnEnd not FactionIsLocal
            
            if I_SettlementOwner Bremen = hungary
                and not I_SettlementUnderSiege Bremen
                and I_TurnNumber < 101
                set_counter Bremen_siege 0
            end_if
            if I_SettlementOwner Stade = hungary
                and not I_SettlementUnderSiege Stade
                and I_TurnNumber < 51
                set_counter Stade_siege 0
            end_if
            if I_SettlementOwner Nordenham = hungary
                and not I_SettlementUnderSiege Nordenham
                and I_TurnNumber < 51
                set_counter Nordenham_siege 0
            end_if
            if I_SettlementOwner Stuttgart = turks
                and not I_SettlementUnderSiege Stuttgart
                and I_TurnNumber < 101
                set_counter Stuttgart_siege 0
            end_if
            if I_SettlementOwner Moempelgard = turks
                and not I_SettlementUnderSiege Moempelgard
                and I_TurnNumber < 51
                set_counter Moempelgard_siege 0
            end_if
            if I_SettlementOwner Aschaffenburg = egypt
                and not I_SettlementUnderSiege Aschaffenburg
                and I_TurnNumber < 101
                set_counter Aschaffenburg_siege 0
            end_if
            if I_SettlementOwner Mainz = egypt
                and not I_SettlementUnderSiege Mainz
                and I_TurnNumber < 51
                set_counter Mainz_siege 0
            end_if
            if I_SettlementOwner Erfurt = egypt
                and not I_SettlementUnderSiege Erfurt
                and I_TurnNumber < 50
                set_counter Erfurt_siege 0
            end_if
            if I_SettlementOwner Heiligenstadt = egypt
                and not I_SettlementUnderSiege Heiligenstadt
                and I_TurnNumber < 51
                set_counter Heiligenstadt_siege 0
            end_if
            if I_SettlementOwner Muenchen = portugal
                and not I_SettlementUnderSiege Muenchen
                and I_TurnNumber < 101
                set_counter Muenchen_siege 0
            end_if
            if I_SettlementOwner Freising = portugal
                and not I_SettlementUnderSiege Freising
                and I_TurnNumber < 51
                set_counter Freising_siege 0
            end_if
            if I_TurnNumber > 100
                terminate_monitor
            end_if
            
        end_monitor
        
        ;--- disbanding garison ---
        monitor_event FactionTurnStart FactionType hungary
            and not FactionIsLocal
            if I_CompareCounter Bremen_siege < 1
                and I_CompareCounter Stade_siege < 1
                and I_CompareCounter Nordenham_siege < 1
                destroy_units hungary garnison
            end_if
            if I_TurnNumber > 100
                terminate_monitor
            end_if
            
        end_monitor
        
        monitor_event FactionTurnStart FactionType turks
            and not FactionIsLocal
            if I_CompareCounter Stuttgart_siege < 1
                and I_CompareCounter Moempelgard_siege < 1
                destroy_units turks garnison
            end_if
            if I_TurnNumber > 100
                terminate_monitor
            end_if
            
        end_monitor
        
        monitor_event FactionTurnStart FactionType egypt
            and not FactionIsLocal
            if I_CompareCounter Mainz_siege < 1
                and I_CompareCounter Aschaffenburg_siege < 1
                and I_CompareCounter Erfurt_siege < 1
                and I_CompareCounter Heiligenstadt_siege < 1
                destroy_units egypt garnison
            end_if
            if I_TurnNumber > 100
                terminate_monitor
            end_if
            
        end_monitor
        
        monitor_event FactionTurnStart FactionType portugal
            and not FactionIsLocal
            if I_CompareCounter Muenchen_siege < 1
                and I_CompareCounter Freising_siege < 1
                destroy_units portugal garnison
            end_if
            if I_TurnNumber > 100
                terminate_monitor
            end_if
            
        end_monitor



  3. #3

    Default Re: Looking for a Garrison Script template

    thanks for the answer

    yeah i see, suspected as much, which is why i said i am willing to compromise so to cut it down a bit to make it simpler

    ok so no disbanding, it does infact seem more trouble than its worth
    no cooldown althrough i dont see how that could be abused, seems to me like the opposite would be true where a faction's settlement gets sieged a few times in a row and gets a crapload of units, but i wouldnt mind that too much since AI could really use a bit of help with recruiting

    so let's see with these conditions:

    Must absolutely work AI vs AI, this is the most important one

    Only works for a single faction, for example England gets 3 settlements to have garrirson script, London, Winchestere and Nottingham, if any of these are attacked the garrison script will activate, however if London is owned by another faction say France then the script wont activate when London gets sieged

    i definitely dont want that 100 turn thing


    so is there a good and simple template with just these things ?
    You know you've played too much Stainless Steel when in every other mod you play you think cavalry is too weak.

  4. #4
    Gigantus's Avatar The trouble with having an open mind, of course, is that people will insist on coming along and trying to put things in it
    Patrician Moderator Emeritus Administrator Emeritus Modding Emeritus

    Join Date
    Aug 2006
    Location
    Goa - India
    Posts
    46,607
    Blog Entries
    24

    Default Re: Looking for a Garrison Script template

    Abuse: start siege, garrison spawns, break off siege, garrison disbands, cool down starts, start siege again, no garrison, == abuse
    no disbanding: attacking AI may withdraw due to sudden strength increase of opponent or attack fails due to bad odds now, leaves 'free' units for the besieged - the major gripe about simple garrison scripts

    What you want is the utterly simple, basic garrison script with AI defender only condition and faction restriction (and including the inherent accumulation of troops for the AI):

    Code:
        monitor_event GeneralAssaultsResidence IsTargetRegionOneOf [region name]
            and I_SettlementUnderSiege [settlement name]  ; required to exclude possible forts in region
            and I_SettlementOwner [defending faction name]
            and I_IsFactionAIControlled [defending faction name]  ; defender must be AI controlled, works in hotseat
    
                create_unit [settlement name], [unit name], num [number of units], exp 0, arm 0, wep 0
    
        end_monitor



  5. #5
    QuintusSertorius's Avatar EBII Hod Carrier
    Artifex

    Join Date
    Feb 2008
    Location
    UK
    Posts
    11,401

    Default Re: Looking for a Garrison Script template

    There's no such thing as a simple template for something intrinsically complex. Here's another example of a garrison script that we use in EBII:

    Code:
        monitor_event FactionTurnEnd FactionType slave
            ; --- Nisaya ----
            if I_IsFactionAIControlled f_parthia            ; script is 'AI only'
                and I_SettlementOwner sett_154 = f_parthia     ; is owned by Pahlava
                and I_SettlementUnderSiege sett_154            ; makes sure the settlement (not a fort)
                if I_EventCounter Nisaya_spawn < 1         ; checking for cool down period
                    console_command create_unit sett_154 "steppe cavalry dahae horse archers" 1 0 0 0
                    console_command create_unit sett_154 "steppe cavalry dahae horse archers" 1 0 0 0
                    console_command create_unit sett_154 "steppe cavalry parthian horse archers" 1 0 0 0
                    console_command create_unit sett_154 "steppe cavalry dahae skirmishers" 1 0 0 0
                    console_command create_unit sett_154 "steppe cavalry parthian horse archers" 1 0 0 0
                    console_command create_unit sett_154 "steppe cavalry dahae skirmishers" 1 0 0 0
                    console_command create_unit sett_154 "steppe infantry gundi nizagan" 1 0 0 0
                    console_command create_unit sett_154 "steppe infantry parthian archers" 1 0 0 0
                    console_command create_unit sett_154 "steppe infantry gundi nizagan" 1 0 0 0
                    console_command create_unit sett_154 "steppe infantry parthian archers" 1 0 0 0
                    set_event_counter Nisaya_spawn 10       ; setting cool down period
                    inc_counter unitlimit_f_parthia 10
                end_if
                if I_EventCounter Nisaya_spawn > 0
                    inc_event_counter Nisaya_spawn -1
                end_if
            end_if
            ; add a loop for each subsequent settlement
        end_monitor
    This is a per-settlement script, where there is one loop like the above per settlement. It fires on the Rebel turn, so won't happen instantly and required a between turn to happen in order to spawn the units. It has a 10-turn cooldown and only spawns if the faction owning the settlement is the AI. It creates the units one at a time, because as soon as the garrison is full, the code stops.

    The advantage of this script is efficiency - you get every spawn in one monitor, which greatly reduces the processing load. Anything linked to launching an assault or a capture will require one monitor per settlement per faction - which means potentially thousands of monitors.

    Note this is a limited application script that only works for the faction capitals, when the starting faction owns them (and is AI-controlled); if you wanted it to only apply to the AI, but for other factions, you'd need to replicate the above for every other faction, changing the I_IsFactionAIControlled and I_SettlementOwner each time.

  6. #6
    Gigantus's Avatar The trouble with having an open mind, of course, is that people will insist on coming along and trying to put things in it
    Patrician Moderator Emeritus Administrator Emeritus Modding Emeritus

    Join Date
    Aug 2006
    Location
    Goa - India
    Posts
    46,607
    Blog Entries
    24

    Default Re: Looking for a Garrison Script template

    It does have the drawback that it does not prevent 'instant attacks' with siege equipment but unlike with my template** it can be merged into one monitor for all permutations of cities and factions which reduces processing time.

    Essentially it uses the same conditions but a different event.

    ** One monitor per city for all faction permutations.
    Last edited by Gigantus; June 15, 2019 at 07:13 AM.



  7. #7
    QuintusSertorius's Avatar EBII Hod Carrier
    Artifex

    Join Date
    Feb 2008
    Location
    UK
    Posts
    11,401

    Default Re: Looking for a Garrison Script template

    Indeed, it's designed with the caveat that you're not going to catch insta-assaults. That's the trade-off, you get an efficient script, but won't catch the fast ones.

  8. #8

    Default Re: Looking for a Garrison Script template

    that might not be an issue really as i already play with home rule of no instant sieges though the tempation is always there

    alright thanks for the help mates
    You know you've played too much Stainless Steel when in every other mod you play you think cavalry is too weak.

  9. #9

    Default Re: Looking for a Garrison Script template

    @QuintusSertorius

    le script spawned only half of the unit amount

    Code:
        monitor_event FactionTurnEnd FactionType slave
            ; --- London ----
            if I_IsFactionAIControlled england            ; script is 'AI only'
                and I_SettlementOwner London = england     ; is owned by Pahlava
                and I_SettlementUnderSiege London            ; makes sure the settlement (not a fort)
                if I_EventCounter London_spawn < 1         ; checking for cool down period
                    console_command create_unit London "Fyrd Spearmen" 10 0 0 0
                    set_event_counter LondonC_spawn 10       ; setting cool down period
                    inc_counter unitlimit_england 10
                end_if
                if I_EventCounter London_spawn > 0
                    inc_event_counter LondonC_spawn -1
                end_if
            end_if
            ; add a loop for each subsequent settlement
        end_monitor
    i told it to get 10 but it spawned only 5 of those spearman, why ?

    EDIT: oh i just noticed "inc_counter unitlimit_england 10" *facepalm*
    Last edited by Dekhatres; June 15, 2019 at 09:47 PM.
    You know you've played too much Stainless Steel when in every other mod you play you think cavalry is too weak.

  10. #10
    Gigantus's Avatar The trouble with having an open mind, of course, is that people will insist on coming along and trying to put things in it
    Patrician Moderator Emeritus Administrator Emeritus Modding Emeritus

    Join Date
    Aug 2006
    Location
    Goa - India
    Posts
    46,607
    Blog Entries
    24

    Default Re: Looking for a Garrison Script template

    That isn't connected to the spawn - it's a counter for the recruit limit script. If memory serves then 5 is actually the limit of units per script line. Add another line with 10 underneath it - that should result in a total of 10, confirming it.



  11. #11

    Default Re: Looking for a Garrison Script template

    yea i just tested and found out *double facepalm*

    alright, so if i wanted for example to add only 1 Feudal Knights unit i would have to put a "2" in there ? or if i want 2 units then i must type 4 ?

    also what happens when thre's no space left in the settlement ? does it spawn the units outside or not at all ?
    Last edited by Dekhatres; June 15, 2019 at 10:30 PM.
    You know you've played too much Stainless Steel when in every other mod you play you think cavalry is too weak.

  12. #12
    Gigantus's Avatar The trouble with having an open mind, of course, is that people will insist on coming along and trying to put things in it
    Patrician Moderator Emeritus Administrator Emeritus Modding Emeritus

    Join Date
    Aug 2006
    Location
    Goa - India
    Posts
    46,607
    Blog Entries
    24

    Default Re: Looking for a Garrison Script template

    Nope, it's just that you will need additional lines of the same unit if you wish to spawn more then 5 units.

    unit1: 5 + 5 + 1 = 11 spawned
    unit2: 3 = 3 spawned


    Note: the spawn will only fill up a garrison\army to 20 units, any excess will get ignored. If you want to spawn a variety of units but expect a certain number of already present units then it's advisable to 'stretch' the spawn to have a proportional garrison, example:

    already present = 12
    unit1 = 4
    unit2 = 1
    unit1 = 4
    unit2 = 1
    unit1 = 3
    unit2 = 1

    total 26 units, cut of will remove the last three spawn and one unit1

    If you used the top 5+5+1+3 spawn none of unit2 would get spawned
    Last edited by Gigantus; June 15, 2019 at 11:27 PM.



  13. #13
    QuintusSertorius's Avatar EBII Hod Carrier
    Artifex

    Join Date
    Feb 2008
    Location
    UK
    Posts
    11,401

    Default Re: Looking for a Garrison Script template

    Yep, as Gig said, you don't need the unit_limit line, that's from another mechanic entirely.

    The addition is deliberately done one unit per line, so that if the garrison is already half full, you don't lose lots of the spawns due to it being over the 20 unit maximum.
    Last edited by QuintusSertorius; June 16, 2019 at 06:54 AM.

  14. #14

    Default Re: Looking for a Garrison Script template

    yeah i see now, well thanks again guys
    You know you've played too much Stainless Steel when in every other mod you play you think cavalry is too weak.

  15. #15
    Gigantus's Avatar The trouble with having an open mind, of course, is that people will insist on coming along and trying to put things in it
    Patrician Moderator Emeritus Administrator Emeritus Modding Emeritus

    Join Date
    Aug 2006
    Location
    Goa - India
    Posts
    46,607
    Blog Entries
    24

    Default Re: Looking for a Garrison Script template




  16. #16
    Withwnar's Avatar Script To The Waist
    Join Date
    Oct 2008
    Location
    Earth
    Posts
    6,082

    Default Re: Looking for a Garrison Script template

    An alternative to GeneralAssaultsResidence is Transgression:

    Code:
    monitor_event Transgression TransgressionName = TC_INSTIGATE_SIEGE
    These threads explain why it's better...

    https://www.twcenter.net/forums/show...1#post14076281
    http://www.twcenter.net/forums/showt...1#post14898642

  17. #17
    QuintusSertorius's Avatar EBII Hod Carrier
    Artifex

    Join Date
    Feb 2008
    Location
    UK
    Posts
    11,401

    Default Re: Looking for a Garrison Script template

    Can it be used to do multiple settlements in one monitor, or is it one monitor per settlement, like GeneralAssaultsResidence?

  18. #18
    Gigantus's Avatar The trouble with having an open mind, of course, is that people will insist on coming along and trying to put things in it
    Patrician Moderator Emeritus Administrator Emeritus Modding Emeritus

    Join Date
    Aug 2006
    Location
    Goa - India
    Posts
    46,607
    Blog Entries
    24

    Default Re: Looking for a Garrison Script template

    It requires the settlement name condition so it will be one monitor per settlement.



  19. #19
    Withwnar's Avatar Script To The Waist
    Join Date
    Oct 2008
    Location
    Earth
    Posts
    6,082

    Default Re: Looking for a Garrison Script template

    No, three monitors in total - and I don't mean three per settlement. The script is in the post of that first link.

    The second link itself has a link to an important finding: that GeneralAssaultsResidence doesn't seem to work for AI vs AI because of the lateness of its unit spawns, too late to be factored into the battle odds calculation and therefore outcome of the battle.

  20. #20
    bitterhowl's Avatar Biarchus
    Join Date
    Feb 2011
    Location
    Russian Feodality
    Posts
    607

    Default Re: Looking for a Garrison Script template

    And what about garrison disbanding in Transgression method?

    My sister, do you still recall
    The blue Hasan and Khalkhin-Gol?

    Because AI is dumb and full of errors.

Page 1 of 2 12 LastLast

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •