If you really must have KH able to build new polis' it's really not hard to do.
To your campaign_script, you add the following in the "11. Colony Management" section:
Code:
;;; Special KH polis-building script ;;;
set_event_counter ecKoinonColonistsOn 0
declare_counter KoinonColonyPoints
monitor_event PreFactionTurnStart
if I_CompareCounter FactionTurnInProgress = 5 ;;; it is the KH turn
and I_IsFactionAIControlled f_kh
set_event_counter ecKoinonColonistsOn 1
end_if
end_monitor
;; Test how many Metropoleis Koinon Hellenon controls:
monitor_event SettlementTurnStart FactionType f_kh
and I_EventCounter ecOlympicYear = 1
and I_EventCounter ecSpring = 1
and SettlementBuildingExists = polis_three
inc_counter KoinonColonyPoints 1
if I_IsFactionAIControlled f_kh ;;; for the AI it is not needed
terminate_monitor
end_if
end_monitor
monitor_event FactionTurnStart FactionType f_kh
if I_IsFactionAIControlled f_kh ;;; for the AI it is not needed
terminate_monitor
end_if
;
if I_CompareCounter KoinonColonyPoints > 0
set_event_counter ecKoinonColonistsOn 1
end_if
end_monitor
monitor_event AddedToBuildingQueue FactionType f_kh
and BuildingName = polis_one
inc_counter KoinonColonyPoints -1
if I_IsFactionAIControlled f_kh ;;; for the AI it is not needed
terminate_monitor
end_if
;
if I_CompareCounter KoinonColonyPoints = 0
set_event_counter ecKoinonColonistsOn 0
end_if
end_monitor
;
; Re-enable the event counter after the player has clicked the end turn button. If this isn't done, the colony building will never complete.
;
monitor_event ButtonPressed ButtonPressed end_turn
if I_IsFactionAIControlled f_kh ;;; for the AI it is not needed
terminate_monitor
end_if
;
if not I_IsFactionAIControlled f_kh
set_event_counter ecKoinonColonistsOn 1
end_if
end_monitor
;
; Disable the event counter at the end of faction turn - applies for both the player as well as the AI.
;
monitor_event FactionTurnEnd FactionType f_kh
set_event_counter ecKoinonColonistsOn 0
end_monitor
Meanwhile in your EDB, find "polis_one requires" and add to the end of the line:
Code:
or event_counter ecKoinonColonistsOn 1
Delete your map.rwm, start a new campaign and bam, KH can build new polis_ones.