Miniscript to hide/unhide stratmap-ui whilst ingame

**Userpro** · November 08, 2009, 11:09 AM

This little first-time-feature script is able to hide & unhide the entire stratmap user interface by simply pressing the "SCROLL_LOCK key" whilst ingame on the stratmap.
I've initally created this nice script only, to make better campaign-map screenshots for our mod. But i think some people out there would appreciate, to add this little feature in their game, also to increase the overall visibility on the stratmap, so i decided to make it public.

But if anybody would like to use this inedited feature in a public mod, it would be only sane, to leave a little note and/or credit, maybe in favour to our RAE-mod, or the RAE-team (see signature), coz our mod is still in development and this script its a inherent part of it!
______________________________

Add the following little piece of lines to your campaign_script.txt located in ...
X:\Games\Medieval II TotalWar\mods\your-mod\data\world\maps\campaign\imperial_campaign\

Code:

declare_counter ui_showing
monitor_event ShortcutTriggered ShortcutTriggered object_manager hide_gui
        wait 0.1
            if I_CompareCounter ui_showing = 0
                hide_ui
                disable_movie_view
                set_counter ui_showing 2
            end_if
            if I_CompareCounter ui_showing = 1
                show_ui
                set_counter ui_showing 0
            end_if
            if I_CompareCounter ui_showing = 2
                set_counter ui_showing 1
            end_if
    end_monitor

Not savegame compatible!

**Squid** · November 08, 2009, 03:24 PM

You can simplify it as follows:

Code:

 monitor_event ShortcutTriggered ShortcutTriggered object_manager hide_gui
      wait 0.5
      if I_CompareCounter ui_showing = 1
           hide_ui
           disable_movie_view
           set_counter ui_showing 0
      end_if
       if I_CompareCounter ui_showing = 0
           show_ui
           set_counter ui_showing 1
       end_if
end_monitor

Since counters start with a value of 0, the first time the monitor is triggered the ui will appear, the second time the monitor is triggered the ui will disappear. You may actually want to swap the disappear and reappear commands as right now scroll lock needs to be pressed twice to see a change.

**Userpro** · November 08, 2009, 04:22 PM

Originally Posted by Sqυιd

You can simplify it as follows:

Spoiler Alert, click show to read:

Since counters start with a value of 0, the first time the monitor is triggered the ui will appear, the second time the monitor is triggered the ui will disappear. You may actually want to swap the disappear and reappear commands as right now scroll lock needs to be pressed twice to see a change.

This one will not work, Sqυιd. Coz if you set counter to 0 in the first "if" condition, the next "if" condition will also apply - and doing so in the same monitor event, they will annul each other.
Not for nothing my above script is a bit more wilier (and looks a bit more chaotic).

Added:
I forgot to add the declare counter line. I've caught it up now!

**The Border Reiver** · November 09, 2009, 01:06 AM

Brilliant job Userpro, I always wondered why this wasn't a default option in MTW2. Rep +

I will add this to my mod for when I test!

**Squid** · November 09, 2009, 09:52 AM

Originally Posted by Userpro

This one will not work, Sqυιd. Coz if you set counter to 0 in the first "if" condition, the next "if" condition will also apply - and doing so in the same monitor event, they will annul each other.
Not for nothing my above script is a bit more wilier (and looks a bit more chaotic).

Added:
I forgot to add the declare counter line. I've caught it up now!

You're right I was missing a counter for the if statements. The other thing you're missing is having movie view re-enabled. Currently you are disabling it, but have no mechanism for re-enabling it.

Code:

declare_counter ui_showing
declare_counter ui_changed
monitor_event ShortcutTriggered ShortcutTriggered object_manager hide_gui
    wait 0.5
    set_counter ui_changed = 0
    if I_CompareCounter ui_showing = 0
         hide_ui
         disable_movie_view
         set_counter ui_showing 0
         set_counter ui_changed 1
    end_if
    if I_CompareCounter ui_showing = 1 and I_CompareCounter ui_changed = 0
         show_ui
         set_counter ui_showing 1
    end_if
end_monitor

**Userpro** · November 09, 2009, 10:07 AM

I think that nobody will miss the "black movie mode restriction bars" and after re-enabling the ui, it seems that the restriction bars will re-appear automatically. This could be the response of a non-existing "enable_movie_view" counterpart command.

**Squid** · November 09, 2009, 11:36 AM

Moved to text editing and scripting.

**Userpro** · November 09, 2009, 12:13 PM

Thanks Squid.
I would like to point out that i edited slightly the above script to identify the very first key-stroke immediately!

**Gigantus** · November 10, 2009, 11:19 AM

That is going to enhance screen shots tremendously!

**Userpro** · November 10, 2009, 07:05 PM

If anybody would like to use this inedited feature in a public mod, it would be only sane, to leave a little note and/or credit, maybe in favour to our RAE-mod, or the RAE-team (see signature), coz our mod is still in development and this script its a inherent part of it!

That is going to enhance screen shots tremendously!

That was initaly the basic reason to create this little jewel.

**gracul** · November 11, 2009, 12:01 PM

Nice script!
Anyway to assign it to F12?

Code:

declare_counter ui_hidden
monitor_event ShortcutTriggered ShortcutTriggered object_manager hide_gui
  inc_counter ui_hidden 1
  if I_CompareCounter ui_hidden = 1
    hide_ui
    disable_movie_view
  end_if
  if I_CompareCounter ui_hidden = 2
    show_ui
    set_counter ui_hidden 0
  end_if
end_monitor

**Userpro** · November 11, 2009, 12:39 PM

Nice script!
Anyway to assign it to F12?

Thats impossible until you're able to remap the shortcut settings.
Your script above looks okay, don't know if it works. You know that there will be always many little variations to script the same thing!

**gracul** · November 11, 2009, 02:18 PM

It works and is probably the easiest way to script it.

**Userpro** · November 11, 2009, 02:24 PM

If it really works then you've saved one "IF" cycle within one monitor-event. Its not a big profit, but it's still a profit.

Edit:
The imperceptible wait-state i've added to stay on the safe side for all mods in all situations, coz internal key-buffering depends on the different states, of the current mod-workload, when u are pressing the key!

**The Border Reiver** · November 12, 2009, 04:43 AM

Userpro, thankyou. I've updated my script accordingly.

**weissnicht** · November 14, 2009, 01:00 PM

great Work as always mate

**Gigantus** · July 12, 2015, 11:17 PM

By now I have included it in every mod I have worked on - really great stuff for screenshots. I am using it in conjunction with this tut of mine.

**Gigantus** · March 09, 2016, 11:55 PM

And now I have a keyboard that hasn't got a scroll lock button - that's a pain.

I managed to find a small application called SharpKeys with which I have to assigned F12 as Scroll Lock button, trying to assign a key via the in game option just isn't flexible enough.

Simply enter the button you want to use (make sure it isn't a button you normally use) in the From column and then select the Scroll Lock key in the To column. After that choose Write to Registry and restart your computer for the changes to take effect.

**Gigantus** · December 14, 2018, 10:50 AM

Just had a user complain that his save game got busted because he saved while the UI was disabled, couldn't re-enable it after reloading. Here now a recovery based on the original script:

Code:

    ; --- Hide UI, press Scroll Lock, by UserPro ---

    declare_counter ui_showing
    monitor_event ShortcutTriggered ShortcutTriggered object_manager hide_gui
        wait 0.1
        if I_CompareCounter ui_showing = 0
            hide_ui
            disable_movie_view
            set_counter ui_showing 2         ; disabled state
        end_if
        if I_CompareCounter ui_showing = 1
            show_ui
            set_counter ui_showing 0         ; default state
        end_if
        if I_CompareCounter ui_showing = 2
            set_counter ui_showing 1         ; interim state
        end_if
    end_monitor

    ; --- Hide UI reset ---

    monitor_event GameReloaded TrueCondition
        if I_CompareCounter ui_showing = 2   ; disabled state
            set_counter ui_showing 0         ; default state
            show_ui                          ; enable UI
        end_if
        if I_CompareCounter ui_showing = 1   ; interim state
            set_counter ui_showing 0         ; default state
            show_ui                          ; enable UI
        end_if
    end_monitor

**Withwnar** · December 21, 2018, 08:16 PM

GameReloaded saves the day again!

The "interim/disabled" comments are back to front. A minor thing but some people trying to understand what it's doing might be confused by this.

You could also do this to save a few lines and duplication...

Code:

    monitor_event GameReloaded TrueCondition
        if not I_CompareCounter ui_showing = 0
            set_counter ui_showing 0         ; default state
            show_ui                          ; enable UI
        end_if
    end_monitor

...or...

Code:

if I_CompareCounter ui_showing != 0

~~~

A word of caution for anybody wanting to use this in a script which has other show/hide UI behaviour in it: every time that other script shows or hides the UI it must also set this ui_showing counter accordingly, so this (thread's) script knows what the current state truly is.

e.g. Another script that, for cinematic effect, hides the UI, does something, then re-shows the UI. If UI was hidden at the time that that other script happens then, after it, the UI will be visible again but ui_showing will still be saying that it's hidden. The next hit of the shortcut key won't do anything - it will need to be hit twice to hide the UI.

Hmm, worse: your GameReloaded bit would fail to do its job, Gigantus. It would be safer to just remove the counter test from it...

Code:

    monitor_event GameReloaded TrueCondition
        set_counter ui_showing 0         ; default state
        show_ui                          ; enable UI
    end_monitor

~~~

Regarding the "F12 key" solution, it (and others) can be added into the game as a shortcut key without the need for 3rd party applications: http://www.twcenter.net/forums/showt...pting-purposes