6 TPY

[Deisi]

Well after playing a couple of more Grand Campaigns I've decided that 6 TPY would be my favorite way to play and I've started a 6 TPY campaign by modifying the descr_strat the way k/t showed me but setting the timescale to 0.16666, the change does produce 6 TPY. I would like to be able to program the weather the way k/t showed Hereward with a 4 TPY campaign (I tried the weather programming using the 4 TPY campaign_script change and it worked perfectly with one winter turn and 3 summer turns) So I have tried modifying the 4 TPY campaign_script change to reflect a 2 winter and 4 summer 6TPY with the seasons in two blocks. I have been unsucessful and it ends up alternating summer and winter turns throughout the year. Admittedly I don't know how to program the mod and I was just trying to use k/t's knowledge and modifying it to 6TPY, so if anyone with more knowledge than I could either show me how it's done or perhaps direct me to where I might learn, it would be greatly appreciated. Cheers.

[k/t]

For something like this, it's always better to ask in the Mod Workshop.

Here's the seasons script from 1648 2.0's campaign_script:

Spoiler Alert, click show to read: 

; === 12 Turns per year ===

;--- timescale has to be 0.0835
;--- start has to be winter
declare_counter month
declare_counter winter_severity
set_counter winter_severity 1 ; normal winter, 2 = severe winter, 3 = mild winter
set_counter month 1 ; set to January

monitor_event PreFactionTurnStart FactionIsLocal ; set the season for each month
if I_CompareCounter month == 1 ; January
and I_CompareCounter winter_severity == 1 ; normal winter
console_command season winter
end_if

if I_CompareCounter month == 1 ; January
and I_CompareCounter winter_severity == 2 ; severe winter
console_command season winter
end_if

if I_CompareCounter month == 1 ; January
and I_CompareCounter winter_severity == 3 ; mild winter
console_command season summer
end_if

if I_CompareCounter month == 2 ; February
and I_CompareCounter winter_severity == 1 ; normal winter
console_command season winter
set_event_counter summer_winter 1 ; next turn will be summer
end_if

if I_CompareCounter month == 2 ; February
and I_CompareCounter winter_severity == 2 ; severe winter
console_command season winter
end_if

if I_CompareCounter month == 2 ; February
and I_CompareCounter winter_severity == 3 ; mild winter
console_command season summer
end_if

if I_CompareCounter month == 3 ; March
and I_CompareCounter winter_severity == 1 ; normal winter
console_command season summer
end_if

if I_CompareCounter month == 3 ; March
and I_CompareCounter winter_severity == 2 ; severe winter
console_command season winter
end_if

if I_CompareCounter month == 3 ; March
and I_CompareCounter winter_severity == 3 ; mild winter
console_command season summer
end_if

if I_CompareCounter month == 4 ; April
and I_CompareCounter winter_severity == 1 ; normal winter
console_command season summer
end_if

if I_CompareCounter month == 4 ; April
and I_CompareCounter winter_severity == 2 ; severe winter
console_command season winter
set_event_counter summer_winter 1 ; next turn will be summer
end_if

if I_CompareCounter month == 4 ; April
and I_CompareCounter winter_severity == 3 ; mild winter
console_command season summer
end_if

if I_CompareCounter month == 5 ; May
console_command season summer
end_if

if I_CompareCounter month == 6 ; June
console_command season summer
end_if

if I_CompareCounter month == 7 ; July
console_command season summer
end_if

if I_CompareCounter month == 8 ; August
console_command season summer
end_if

if I_CompareCounter month == 8 ; August
and I_CompareCounter winter_severity == 2 ; severe winter
set_event_counter summer_winter 2 ; next turn will be winter
end_if

if I_CompareCounter month == 9 ; September
and I_CompareCounter winter_severity == 1 ; normal winter
console_command season summer
set_event_counter summer_winter 2 ; next turn will be winter
end_if

if I_CompareCounter month == 9 ; September
and I_CompareCounter winter_severity == 2 ; severe winter
console_command season winter
campaign_wait 1
historic_event severe_winter
end_if

if I_CompareCounter month == 9 ; September
and I_CompareCounter winter_severity == 3 ; mild winter
console_command season summer
end_if

if I_CompareCounter month == 10 ; October
and I_CompareCounter winter_severity == 1 ; normal winter
console_command season winter
end_if

if I_CompareCounter month == 10 ; October
and I_CompareCounter winter_severity == 2 ; severe winter
console_command season winter
end_if

if I_CompareCounter month == 10 ; October
and I_CompareCounter winter_severity == 3 ; mild winter
console_command season summer
campaign_wait 1
historic_event mild_winter
end_if

if I_CompareCounter month == 11 ; November
and I_CompareCounter winter_severity == 1 ; normal winter
console_command season winter
end_if

if I_CompareCounter month == 11 ; November
and I_CompareCounter winter_severity == 2 ; severe winter
console_command season winter
end_if

if I_CompareCounter month == 11 ; November
and I_CompareCounter winter_severity == 3 ; mild winter
console_command season summer
set_event_counter summer_winter 2 ; next turn will be winter
end_if

if I_CompareCounter month == 12 ;December
console_command season winter
end_if

if I_CompareCounter month == 12 ; December
and I_CompareCounter winter_severity == 3 ; mild winter
set_event_counter summer_winter 1 ; next turn will be summer
end_if

inc_counter month 1 ; advance the month
if I_CompareCounter month == 13 ; start a new year
set_counter month 1
end_if
end_monitor

monitor_event FactionTurnEnd FactionType slave ; allows game to advance age
and I_CompareCounter month < 12
console_command season summer
end_monitor

monitor_event FactionTurnEnd FactionType slave ; randomized winter
and I_CompareCounter month == 6
generate_random_counter random_winter 1 10
if I_EventCounter random_winter >= 1
and I_EventCounter random_winter <= 8
set_counter winter_severity 1 ; 80 percent chance of regular winter
end_if

if I_EventCounter random_winter == 9
set_counter winter_severity 2 ; 10 percent chance of severe winter
end_if

if I_EventCounter random_winter == 10
set_counter winter_severity 3 ; 10 percent chance of mild winter
end_if
end_monitor

It might give you some hints on how to do it, since 1648 uses 12 TPY. From what I've seen, you need "console_command season winter" commands.

[Deisi]

Wow, thanks a lot. I'm such a novice at modding. I will do some research at the Mod Workshop which for some reason never occurred to me, so thanks k/t for your time and advice

[Deisi]

Just for fun I used the 12 TPY script in TLK and it works great,seasons and all. I'll adapt it to 6 TPY when I'm done with the 12 TPY game